Reproduciendo Sonido
El primer paso es reproducir un determinado archivo de sonido, para ello utilizamos la clase Sound, la cual incluye los métodos necesarios para la reproducción de sonido. Para cargar el sonido utilizamos el método loadSound
var music:Sound = new Sound();
music.loadSound("sound.mp3", true);
music.start(); |
Hasta este punto estamos cargando un archivo llamado sound.mp3 y lo estamos reproduciendo. Lo siguiente es detectar cuando se ha cargado el archivo y cuando se ha terminado de reproducir, esto para controlar adecuadamente el comportamiento del player.
var music:Sound = new Sound();
music.loadSound("sound.mp3", false);
music.onLoad = function() {
// acciones para mostrar el progreso
}
music.onSoundComplete = function() {
// acciones para reiniciar el player
} |
Agregando Barras de Progreso
El siguiente paso es crear los elementos visuales que nos ayudarán a mostrar el comportamiento de nuestro player. Creamos una barra de progreso para nuestro reproductor, con un movieclip: mcTime para mostrar el progreso de la reproducción. Adicionalmente creamos un campo de texto inTime para mostrar en números el avance de la reproducción. Luego implementamos las funciones necesarias para mostrar nuestras barras de progreso.
var mcPath:MovieClip = this;
var wTime:Number = mcTime._width;
var music:Sound = new Sound();
music.loadSound("sound.mp3", false);
music.onLoad = function() {
startProgress();
}
music.onSoundComplete = function() {
stopProgress();
}
function startProgress() {
mcPath.onEnterFrame = function() {
inTime.text = "TIME:"+music.position+"/"+music.duration;
mcTime._width = wTime*(music.position/music.duration);
}
}
function stopProgress() {
delete mcPath.onEnterFrame;
} |
Agregando controles de reproducción
El último paso para tener nuestro reproductor completo es agregarle los controles: btPlay para iniciar la reproducción, btPause para pausar la reproducción, btMute para poner el mudo el sonido y btUnmute para activar el sonido.
var timer:Number = 0;
var mcPath:MovieClip = this;
var wTime:Number = mcTime._width;
var music:Sound = new Sound();
music.loadSound("sound.mp3", false);
music.onLoad = function() {
startProgress();
btPlay.enabled = true;
}
music.onSoundComplete = function() {
timer = 0;
btPlay._visible = true;
stopProgress();
}
function startProgress() {
delete mcPath.onEnterFrame;
mcPath.onEnterFrame = function() {
inTime.text = "TIME:"+music.position+"/"+music.duration;
mcTime._width = wTime*(music.position/music.duration);
}
}
function stopProgress() {
delete mcPath.onEnterFrame;
}
btPlay.enabled = false;
btPlay.onRelease = function() {
music.start(timer/1000);
btPlay._visible = false;
}
btPause.onRelease = function() {
timer = music.position;
music.stop()
stopProgress();
btPlay._visible = true;
}
btMute.onRelease = function() {
music.setVolume(0);
btMute._visible = false;
}
btUnmute.onRelease = function() {
music.setVolume(100);
btMute._visible = true;
} |
Como pueden observar para controlar el volumen hemos utilizado el método setVolume y para hacer la pausa hemos utilizado un artilugio ya que la clase Sound no tiene una propiedad para hacer pausar el sonido, para ello guardamos la posición en la cual se hace el llamado a detener el sonido y luego reproducimos a partir de ese punto.
Tema: crear Reproductor flash 
Sáb Nov 15, 2008 8:18 pm
